Skip to main content

The troubles of extending/correcting a lookup doing a wrong filter when the lookup is based on table relations

 Working in the WHS module a customer needed to be able to change the transport provider (carrier) and the provided service (carrier service) directly on the Shipment chosen in the pack form.

This presents some interesting challenges, working within the limits of the extension mechanisms in D365.

Firstly as of time of writing the application implements a table relation on the WHSShipment table to the table TMSCarrierService (transport service codes provided by a carrier).

It does so by having a Normal field relation between TMSCarrierService.CarrierServiceCode and WHSShipmenttable.CarrierServiceCode, thus NOT taking in to consideration the Carrier that have been chosen on the shipment.




Trouble is that you can not change a table relation using extensions, AND you can not using extensions to introduce a new (correct) relation that overrides the existing one.

So instead of just changing the table relation (if that was possible and simple), I needed to do 4 extensions.

1) A new class with a formDataSource extension on form WHSPack, that unlocks the datasource which is actually non-editable, then locking all fields other than CarrierCode and CarrierServiceCode:

    /// <summary>
    /// Extension of active method on WHSShipmentTable datasource
    /// </summary>
    /// <returns>int</returns>
    int active()
    {
        FormDataSource shipmentFDS = this;
        FormDataObject fob;

        int noOfFieldsInDS,field,fieldID;
        DictTable shipmentDT;

        int ret = next active();

        shipmentDT = new DictTable(shipmentFDS.table());
        noOfFieldsInDS = shipmentDT.fieldCnt(TableScope::CurrentTableOnly);

        shipmentFDS.allowEdit(true);
        for(field=1;field <= noOfFieldsInDS;field++)
        {
            fieldID = shipmentDT.fieldCnt2Id(field);
            fob = shipmentFDS.object(fieldID);
            if (fieldId != fieldNum(WHSShipmentTable,CarrierCode) && fieldId != fieldNum(WHSShipmentTable,CarrierServiceCode))
            {
                if (shipmentFDS.object(fieldID))
                {
                    shipmentFDS.object(fieldID).allowEdit(false);
                }
            }
            else
            {
                if (shipmentFDS.object(fieldID))
                {
                    shipmentFDS.object(fieldID).allowEdit(true);
                }
            }
        }
        return ret;
    }

Now we see that the lookup on CarrierServiceCode is NOT filtered by the chosen Carrier, so what to do ?

2) A new class with a table extension on WHSShipmentTable that implemented a new edit method

[ExtensionOf(tableStr(WHSShipmentTable))]
final class HAINWHSShipmentTable_Extension
{
    public edit TMSCarrierServiceCode editCarrierServiceCode(boolean _set, TMSCarrierServiceCode _carrierServiceCode)
    {
        if (_set)
        {
            ttsbegin;
            this.CarrierServiceCode = _carrierServiceCode;
            this.update();
            ttscommit;
        }
        else
        {
            _carrierServiceCode = WHSShipmentTable::find(this.ShipmentId).CarrierServiceCode;
        }
        return _carrierServiceCode;
    }

}

3) A form extension that disables and makes the WHSShipmentTable_CarrierServiceCode field invisible, and introduces the edit-method from step 2 into the form design, remembering to set the 'Lookup button' property to value 'Always'

4) A class with EventHandlers for lookup on the new field using the edit-method from step 2 and OnModified-event on the CarrierCode field to clear the CarrierServiceCode field when CarrierCode is changed:

/// <summary>
/// Event handler for "over riding" default lookup on TMSCarrierService which is wrong due to table relation between WHSShipmentTable and TMSCarrierService
/// having only CarrierServiceCode defined - not taking in to consideration that a CarrierCode might be present - which SHOULD filter lookup on the chosen carrier
/// So normal field is disabled and a field based on a edit method is introduced, and this is handler helps making the correct lookup (filtered on chosen carrier)
/// </summary>
class HAINWHSPackFormCarrierServiceCodeLookup_EventHandler
{
    

    /// <summary>
    ///
    /// </summary>
    /// <param name="sender"></param>
    /// <param name="e"></param>
    [FormControlEventHandler(formControlStr(WHSPack, editCarrierServiceCode), FormControlEventType::Lookup)]
    public static void editCarrierServiceCode_OnLookup(FormControl _sender, FormControlEventArgs _e)
    {
        Query query;
        QueryBuildDataSource qbds;
        SysTableLookup sysTableLookup;
        FormControlCancelableSuperEventArgs event;
        TMSCarrierCode chosenCarrier;

        event = _e as FormControlCancelableSuperEventArgs;
        chosenCarrier = _sender.formRun().design().controlname(formControlStr(WHSPack,WHSShipmentTable_CarrierCode)).valueStr();

        query = new Query();   
        qbds = query.addDataSource(tableNum(TMSCarrierService));
        if (chosenCarrier)
        {
            qbds.addRange(fieldNum(TMSCarrierService,CarrierCode)).value(queryValue(chosenCarrier));
        }
        sysTableLookup = SysTableLookup::newParameters(tableNum(TMSCarrierService),_sender);
        sysTableLookup.addLookupfield(fieldNum(TMSCarrierService,CarrierServiceCode));
        sysTableLookup.addLookupfield(fieldNum(TMSCarrierService,Name));
        sysTableLookup.parmQuery(query);
        sysTableLookup.performFormLookup();
        event.CancelSuperCall();
    }

    /// <summary>
    ///
    /// </summary>
    /// <param name="sender"></param>
    /// <param name="e"></param>
    [FormDataFieldEventHandler(formDataFieldStr(WHSPack, WHSShipmentTable, CarrierCode), FormDataFieldEventType::Modified)]
    public static void CarrierCode_OnModified(FormDataObject sender, FormDataFieldEventArgs e)
    {
        WHSShipmentTable shipment;
        shipment = sender.datasource().cursor() as WHSShipmentTable;
        shipment.CarrierServiceCode = '';
        shipment.update();
        sender.datasource().reread();

    }

}

If only you could add fields to table relations, or at least make a new relation that replaces the default one.


Sometimes I miss the old days, where thing could be overridden. ;-)

Comments

Post a Comment

Popular posts from this blog

Suppressing the infolog

Supressing the infolog is often useful in D365FO when augmenting code. When augmenting code using COC (Chain Of Command), you can have new code run either before or after the code you are augmenting. This means that any infolog-messages that the standard application code does, will be shown to the user, even if your augmentation supports a scenario where there must be no infolog-messages. How do you avoid the standard application infolog-messages ? To the rescue comes temporary supression of the infolog. The suppression consists of: 1) Saving the current infologLevel 2) Setting the infologLevel to SysInfologLevel::None 3) Run your code 4) Restoring the saved infologLevel to the infolog For example a table could have a validatewrite-method that validates that you are only allowed to use 3 out of 6 options in an enum-field, and you need to allow for a fourth one. Table a - validateWrite method: boolean validateWrite() {     Switch (this.enumField)     {     ...
Post a Comment
Read more

Indicating mandatory field in a dialog (RunBase) class.

A classical problem is indicating that a field is mandatory in a dialog, when the field is not bound to a datasource/field in a datasource. Normally fellow developers will tell you that, that is not possible. I found a way to do this. In your Runbase-based class you can implement the putToDialog-method e.g like this: protected void putToDialog() { super(); fieldMask.fieldControl().mandatory(true); } where fieldMask is a DialogField object in your dialog. This will make the field act like it was a mandatory field from a datasource in a form, showing a red-wavy line under the field, and requiring the field to have a value. Attention: Your class has to run on the client.If you set your class to run on the server, you get a run-time error, when the fieldMask.FieldControl()-call is made.
1 comment
Read more

Dynamics ax 2012 traversing selected records in a form data source

A classical developer challenge in Dynamics AX is to enable a form button when multiple records have been selected in the form by the user. This usually involves writing some form of loop (for or while or do-while) that starts out with calling _ds.getFirst() and continuing the loop as long as _ds.getNext() returns a tablebuffer. Well things got a little bit easier in AX 2012. In AX 2012 you can use the MultiSelectionHelper class. One example is the following that I encountered in AX 2012: Can you make the customer collection letter print out run for each selected collection record in the Print/Post collection letters form (Accounts receiveable / Periodic / Collections / Print/Post Collection letters). If we ignore the possibility for setting up print destination for running each report we can do this in two steps: 1) Change the "Multiselect" property of the "MenuButton" and the "Menuitembutton" in the MenuButton in the form from "Auto...
Post a Comment
Read more